ESP Motor Shield: Controlando Motores via WiFi

Introdução

Há algum tempo, mostramos aqui no blog algumas shields para controle de motor, montagem e programação de plataformas robóticas e até mesmo um controle remoto com Arduino, e hoje não vai ser diferente. Vamos te ensinar a usar a ESP Motor Shield, uma shield para o ESP8266 baseada no chip L293D e que te permite controlar seu carrinho via Wi-Fi, além de todas as possibilidades que o ESP8266 pode nos proporcionar! Mas antes, vamos às apresentações:

Descrição

Chip L293D

ESP8266

Shield

Montagem e Cofiguração

Materiais necessários para o projeto Controlando Motores via WiFi

• 1x Motor Shield L293D para Módulo WiFi ESP8266 NodeMCU V2
• 1x Módulo WiFi ESP8266 NodeMcu ESP-12E
• 1x Kit Chassi 4WD Robô para Arduino (você também pode utilizar um Kit Chassi 2WD (2 rodas) Robô para Arduino)
• 4x pilhas AA
• Smartphone

Montagem

Configuração

• Em Output, mude a opção selecionada para Merge.
• Em Pin, você pode escolher o que quiser, basta informar o selecionado no código. Para o nosso exemplo, vamos usar o V1.
• Repare que ao lado do pino selecionado existe uma inscrição dizendo "To access values use:". Anote esses parâmetros para também os informar no código.

//inclusão de bibliotecas
#include <ESP8266WiFi.h>
#include <BlynkSimpleEsp8266.h>

//definição de funções e pinos
#define BLYNK_PRINT Serial
#define RightMotorSpeed 5
#define RightMotorDir   0 
#define LeftMotorSpeed  4
#define LeftMotorDir    2

//variáveis referentes à conexão WiFi
char auth[] = "*********************";
char nome_rede[] = "*************";
char senha[] = "*********";

//variáveis de controle dos motores
int minRange = 300;
int maxRange = 900;
int minSpeed = 450;
int maxSpeed = 1020;
int noSpeed = 0;


void movimento(int x, int y){
//mover para frente
   if(y >= maxRange && x >= minRange && x <= maxRange){
    digitalWrite(RightMotorDir,HIGH); 
    digitalWrite(LeftMotorDir,HIGH);
    analogWrite(RightMotorSpeed,maxSpeed);
    analogWrite(LeftMotorSpeed,maxSpeed);
  }

//mover para frente e para direita
  else if(x >= maxRange && y >= maxRange){
    digitalWrite(RightMotorDir,HIGH);
    digitalWrite(LeftMotorDir,HIGH);
    analogWrite(RightMotorSpeed,minSpeed);
    analogWrite(LeftMotorSpeed,maxSpeed);
  }

//mover para frente e para esquerda
  else if(x <= minRange && y >= maxRange){
    digitalWrite(RightMotorDir,HIGH);
    digitalWrite(LeftMotorDir,HIGH);
    analogWrite(RightMotorSpeed,maxSpeed);
    analogWrite(LeftMotorSpeed,minSpeed);
  }

  //zona neutra
  else if(y < maxRange && y > minRange && x < maxRange && x > minRange){
    analogWrite(RightMotorSpeed,noSpeed);
    analogWrite(LeftMotorSpeed,noSpeed);
  }

 //mover para trás
  else if(y <= minRange && x >= minRange && x <= maxRange){
    digitalWrite(RightMotorDir,LOW);
    digitalWrite(LeftMotorDir,LOW);
   analogWrite(RightMotorSpeed,maxSpeed);
    analogWrite(LeftMotorSpeed,maxSpeed);
  }

  //mover para trás e para direita
  else if(y <= minRange && x <= minRange){
    digitalWrite(RightMotorDir,LOW);
    digitalWrite(LeftMotorDir,LOW);
    analogWrite(RightMotorSpeed,minSpeed);
    analogWrite(LeftMotorSpeed,maxSpeed); 
  }

  //mover para trás e para esquerda
  else if(y <= minRange && x >= maxRange){
    digitalWrite(RightMotorDir,LOW);
    digitalWrite(LeftMotorDir,LOW);
    analogWrite(RightMotorSpeed,maxSpeed);
    analogWrite(LeftMotorSpeed,minSpeed);
  }
}

void setup(){
//iniciando a comunicação serial para verificação da conexão WiFi  
  Serial.begin(9600);
  Blynk.begin(auth, nome_rede, senha);
 
//setando os pinos referentes aos motores
  pinMode(RightMotorSpeed, OUTPUT);
  pinMode(LeftMotorSpeed, OUTPUT);
  pinMode(RightMotorDir, OUTPUT);
  pinMode(LeftMotorDir, OUTPUT);
  
//iniciando o carrinho com os motores desligados e sentido de rotação à frente
  digitalWrite(RightMotorSpeed, LOW);
  digitalWrite(LeftMotorSpeed, LOW);
  digitalWrite(RightMotorDir, HIGH);
  digitalWrite(LeftMotorDir,HIGH);
}

void loop(){
//comando para execução do código
   Blynk.run();
}

//inserção dos parâmetros informados pelo app
BLYNK_WRITE(V1){               //pino virtual selecionado no joystick
  int x = param[0].asInt();
  int y = param[1].asInt();
  movimento(x,y);
}

//variáveis referentes à conexão WiFi
char auth[] = "*********************"; 
char nome_rede[] = "*************"; 
char senha[] = "*********";

Conclusão

Concluímos aqui a montagem de mais uma plataforma robótica, dessa vez controlado através da rede WiFi. A ESP Motor Shield é uma plaquinha extremamente versátil que nos abre um novo leque de possibilidades nesse segmento de robôs e, uma sugestão que deixamos a você, leitor, é: aperfeiçoe o código, implemente outras funções como controle de velocidade, sensores e outras funcionalidades capazes de automatizar ainda mais o seu robô. Fazendo isso você estará praticando e evoluindo ao máximo seus conhecimentos adquiridos até aqui!Um forte abraço e até a próxima. 

Referências

https://www.instructables.com/Simplest-Wifi-Car-Using-ESP8266-Motorshield/ https://cdn.hackaday.io/files/8856378895104/user-mannual-for-esp-12e-motor-shield.pdf https://blog.eletrogate.com/nodemcu-esp12-introducao-1/ https://blog.eletrogate.com/motor-shield-l293d-driver-ponte-h-para-arduino/

Se interessou por esse projeto? Não deixe de conferir nossa loja e os produtos para evoluir ainda mais o seu projeto. Fez o carrinho? Poste o resultado e nos marque no Instagram @Eletrogate. Estamos ansiosos para ver o seu resultado!Tenha a Metodologia Eletrogate na sua Escola! Conheça nosso Programa de Robótica Educacional.

Sobre o Autor

Samuel Martins @samuel.martins192 Cursando Eletroeletrônica no SENAI CETEL. Fanático por eletrônica, automação, impressão 3D e afins, dedico meu tempo livre a pesquisas e projetos ligados às principais áreas de interesse, pratico aeromodelismo e sou curioso por astrofotografia.